"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" CHOOSE A LOCALE
try let! locale= $LC_ALL ? $LC_ALL : $LANG
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" SET SOME SYSTEM DEFAULTS
set! lptype=ps2 lplines=60 lpcolumns=80 lpwrap ruler showmatch showmode
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" DEFINE SOME DIGRAPHS
if os == "msdos" || os == "os2" || (os == "win32" && gui != "windows")
then source! (elvispath("elvis.pc8"))
else source! (elvispath("elvis.lat"))
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" CHOOSE SOME DEFAULT OPTION VALUES BASED ON THE INVOCATION NAME
switch tolower(basename(program))
case ex
case edit set! initialstate=ex
case view set! defaultreadonly
case edit
case vedit set! novice
if home == ""
then let home=dirdir(program)
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" IF SPELL-CHECKING IS SUPPORTED, THEN LOAD THE DEFAULTS
if feature("spell")
then source! (elvispath("elvis.spe"))
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" IF ALIASES ARE SUPPORTED, THEN LOAD THE DEFAULT ALIASES
if feature("alias") && !safer
then source! (elvispath("elvis.ali"))
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" SYSTEM TWEAKS GO HERE
"
" The Linux console can't handle colors and underlining.  Neither can MS-DOS
" with any of the ANSI drivers.
if gui=="termcap"
then {
 if term=="linux" || (os=="msdos" && (term>>4)=="ansi")
 then set! nottyunderline
 if term=="linux"
 then set! nottyitalic
 if term=="xterm"
 then {
  map! Op 0
  map! Oq 1
  map! Or 2
  map! Os 3
  map! Ot 4
  map! Ou 5
  map! Ov 6
  map! Ow 7
  map! Ox 8
  map! Oy 9
  map! On .
  map! Ok +
  map! Om -
  map! Oj *
  map! Oo /
  map! OM 
  map! OH visual ^
  map OH ^
  map! OF visual $
  map OF $
 }
}
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" Gnome default setup goes here (may be overridden in .exrc file)
if gui=="gnome"
then so! (elvispath("elvis.gnome"))
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" X11 DEFAULT COLORS AND TOOLBAR GO HERE (may be overridden in .exrc file)
if gui=="x11"
then so! (elvispath("elvis.x11"))
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" SOME MAPS THAT MAKE HTML BROWSING EASIER
if feature("html") && feature("autocmd")
then {
 augroup! html
 au!
 " <Space> jumps forward one page
 au DisplayEnter html map nosave command   
 au DisplayLeave html unmap command  
 " <Enter> follows a hypertext link
 au DisplayEnter html map nosave command 
 
 au DisplayLeave html unmap command 
 augroup END
}
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" EXECUTE THE STANDARD CUSTOMIZATION SCRIPTS
let f=(os=="unix" ? ".elvisrc" : "elvis.rc")
if $EXINIT
then eval $EXINIT
else source! (exists(home/f)?home/f:home/".exrc")
source! ~/.elvislib/elvis.rc
if exrc && getcwd()!=home
then safer! (exists(f)?f:".exrc")
set f=""
"
"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
" X11 INTERFACE DEFAULT FONTS GO HERE
if gui == "x11"
then {
 if font == "" && xrootwidth >= 1024
 then {
  set! font="*-courier-medium-r-*-18-*" 
  set! boldfont="*-courier-bold-r-*-18-*" 
  set! italicfont="*-courier-medium-o-*-18-*" 
 }
 if font == "" && xrootwidth >= 800
 then {
  set! font="*-courier-medium-r-*-14-*" 
  set! boldfont="*-courier-bold-r-*-14-*" 
  set! italicfont="*-courier-medium-o-*-14-*" 
 }
 if font == ""
 then {
  set! font="*-courier-medium-r-*-12-*" 
  set! boldfont="*-courier-bold-r-*-12-*" 
  set! italicfont="*-courier-medium-o-*-12-*" 
 }
}
"